ＪＡＮコードの１３桁コードの構成は「企業コード (９桁)」＋「アイテムコード (３桁)」＋「チェックデジット (１桁)」です。
８桁の場合も コードの数が変わるだけで基本的な計算方法は変わりません。 手順を書きますと
例：企業コード／４５６９９５１１１ アイテムコード／１２３
１. コードを右詰に１３桁並べた時の 偶数桁の数字を合計する
「５」＋「９」＋「５」＋「１」＋「１」＋「３」＝「２４」
２. (１)の結果を３倍する
「２４」×３＝「７２」
３. コードを右詰に１３桁並べた時の 奇数桁(Ｃ/Ｄ除く)の数字を合計する
「４」＋「６」＋「９」＋「１」＋「１」＋「２」＝「２３」
４. (２)の結果と (３)の結果を合計する
「７２」＋「２３」＝「９５」
５. (４)の１桁目の数字を「１０」から引く
「１０」−「５」＝「５」
以上です。
計算方法自体は単純なので セルを分けて計算するなら なんてことのない計算ですね。
企業コードを Ａ１セルに入力
アイテムコードを Ｂ１セルに入力
■Ｃ１セル
=TEXT(A1*1000+B1,0)
８桁コードの時は
=TEXT(A1*10+B1,REPT(0,12))
Ａ３：Ａ１４セルに「１〜１２」の連番を入力して
■Ｂ３セル
=MID(C$1,A3,1)*1
縦方向にオートフィルコピー
■Ｃ３セル：奇数合計
=SUM(B3,B5,B7,B9,B11,B13)
これをＣ４セルにコピー
■Ｃ５セル
=C4*3+C3
■Ｃ６セル：チェックデジット
=MOD(10-C5,10)
これで求められます。C6セルの計算式で 先に１０から引いて計算しているのは 桁が「０」の時に「１０」と表示されないようにする為です。
続いて作業セルを使わない方法です。よく考えれば 偶数桁と奇数桁を分けてはいますが
結局全部足し算はする訳です。一文字ずつ切り分けて奇数番目には「１」偶数番目には「３」を掛けて全部足してやっても同じ結果が得られますね。以下１３桁コードの計算式です。
企業コードを Ａ１セルに入力
アイテムコードを Ｂ１セルに入力
■Ｃ１セル
=MOD(10-SUM(MID(A$1*1000+B1,{1,2,3,4,5,6,7,8,9,10,11,12},1)
*{1,3,1,3,1,3,1,3,1,3,1,3}),10)
もしくは
=MOD(10-SUM(MID(A$1*1000+B1,{1,3,5,7,9,11;2,4,6,8,10,12},1)*{1;3}),10)
長ったらしいのが気になるなら [挿入]→[名前]→[定義]で「CD」と名前を付けて
１行目で [挿入]→[名前]→[定義]
[名 前]：ＣＤ
[参照範囲]：
=MOD(10-SUM(MID(!$A$1*1000+!$B1,ROW(!$1:$12),1)
*(1+MOD((ROW(!$1:$12)-1),2)*2)),10)
→[OK]
として
■Ｄ１セル
=A$1*10^4+B1*10+CD
表示形式を[数値] もしくはユーザー定義の「0」に設定
としておく手もあります。
済みません定義付けした数式に誤りがありましたので修正しました
(2011.10.17)
→参考ファイル(037.xlsx)
因みに８桁の場合の計算を一応載せておきますが (10.10.06 追加)
ＪＡＮメーカーコード（６桁）を Ａ１セルに入力
アイテムコード（１桁）を Ｂ１セルに入力
■Ｃ１セル
=MOD(10-SUM(MID(A$1*10+B1,{1,2,3,4,5,6,7},1)*{3,1,3,1,3,1,3}),10)
以上です。